办公密码锁技巧(电子密码锁的安装、调试与维修教学任务)

学习目标

1、 知道单片机的特点及其结构。

2、 识读MCS—51各引脚并掌握其工作原理。。

3、 懂并按要求编写基本的单片机指令。

4、电子密码锁元件的特点。

5、懂电子密码锁原理图。

6、懂电子密码锁安装图。

7、懂电子密码锁的程序。

8、行安装、调试、维修电子密码锁。

学习内容：

1、 单片机的特点及其结构。

2、 识读MCS—51各引脚并掌握其工作原理。

3、 识读指令的结构，类型及编写

4、 电子锁电子元件的特点。

5、电子锁的工作原理、特点、种类。

6、电子锁电子元件的测试。

7、进行电子锁程序的设计。

本学习情境学时:44学时

本课题的教学步骤可分为：

1、下发任务书

2、学习流程

3、引导问题

4、有关表格

5、自我测试题（评价标准、测试题）

任务书

随着生活水平的提高，人们对自己所处环境安全性要求越来越高。本设计主要是基于单片机智能锁的硬件和软件的设计及实现方法，这种电路设计具有按键有效提示,输入错误提示,控制开锁电平,控制报警电路,修改密码等多种功能"可在意外泄密的情况下随时修改密码"4位数密码共一万组不重复组合,保密性强,灵活性高,特别适用于家庭，办公室，学生宿舍及宾馆等公开场所。

通过本课题的学习，你能够独立完成密码锁的组装，并且可以进行它类型密码锁的维修；下图为密码锁电原理图。

图1 电子密码锁原理图

图2 实物图

总体方案设计

设计思路

共设了9个用户输入键，其中只有4个是有效的密码按键，其它的都是干扰按键，若按下干扰键，键盘输入电路自动清零，原先输入的密码无效，需要重新输入；如果用户输入密码的时间超过40秒（一般情况下，用户不会超过40秒，若用户觉得不便，还可以修改）电路将报警80秒，若电路连续报警三次，电路将锁定键盘5分钟，防止他人的非法操作。

采用AT89S51为核心的单片机控制方案。利用单片机灵活的编程设计和丰富的IO端口，及其控制的准确性，不但能实现基本的密码锁功能，还能添加调电存储、声光提示甚至添加遥控控制功能。其原理如图2－2所示。

图2－2单片机控制方案

开锁机构

通过单片机送给开锁执行机构，电路驱动电磁锁吸合，从而达到开锁的目的。其原理如图2－3所示。

图2－3密码锁开锁机构示意图

当用户输入的密码正确时，单片机便输出开门信号，送到开锁驱动电路，然后驱动电磁锁，达到开门的目的。其实际电路如图2－4所示。

电路由驱动和开锁两级组成。由D5、R1、T10组成驱动电路，其中T10可以选择普通的小功率三极管如9014、9018都可以满足要求。D5是开锁指示灯；由D6、C24、T11组成开锁。其中D6、C24是为了消除电磁锁可能产生的反向高电压以及可能产生的电磁干扰。T11可选用中功率的三极管如8050，电磁锁的选用要视情况而定，但是吸合力要足够且有一定的余量。

注：在设计中，暂时用发光二极管代替电磁锁，发光管亮，表示开锁；灭，表示没有开锁。

图2－4密码锁开锁机构电路图

按键电路设计

由于设计要求使用矩阵键盘，所以本设计就采用行列式键盘，同时也能减少键盘与单片机接口时所占用的I/O线的数目，在按键比较多的时候，通常采用这样方法。其原理如图2－5所示。

图2－5 行列式键盘原理电路图

每一条水平（行线）与垂直线（列线）的交叉处不相通，而是通过一个按键来连通，利用这种行列式矩阵结构只需要N条行线和M条列线，即可组成具有N×M个按键的键盘。

首先辨别键盘中有无键按下，有单片机I/O口向键盘送全扫描字，然后读入行线状态来判断。方法是：向行线输出全扫描字00H，把全部列线置为低电平，然后将列线的电平状态读入累加器A中。如果有按键按下，总会有一根行线电平被拉至低电平从而使行线不全为1。判断键盘中哪一个键被按下使通过将列线逐列置低电平后，检查行输入状态来实现的。方法是：依次给列线送低电平，然后查所有行线状态，如果全为1，则所按下的键不在此列；如果不全为1，则所按下的键必在此列，而且是在与零电平行线相交的交点上的那个键。

按键的操作面板如图2－6所示。共计数字键10个，功能键2个。

图2－6按键操作面板示意图

10个数字键用来输入密码，另外2个功能键分别是：开锁和上锁。上锁和开锁的过程在1-2中已经详细介绍,在此不再说。。

面板上还有一个蜂鸣器，其中一个功能是用来指示操作的按键是否在成功的按下；另外一个功能是当用户输入密码错误的次数超过了3次，鸣笛以示报警。

显示电路设计

本系统设计的显示电路为了节约单片机的接口资源而采用串行显示的方式，只使用单片机的两个串行口，就可以完成单片机的显示功能，显示电路的电路原理图如图2－7所示。

电路设定：当程序检测在5分钟内没有按键操作的时候，就关闭显示。这个功能使用程序来实现的，一旦没有按键动作就启动一个定时器，检测在5分钟内没有按键动作的时候，启动一个程序，关闭显示，这样可以达到节省电能的目的。

从单片机串口输出的信号先送到左边的移位寄存器（74HC164）,由于移位脉冲的作用，使数据向右移，达到显示的目的。移位寄存器74HC164还兼作数码管的驱动，插头1（header1）接电源，插头2（header2）接数据和脉冲输出端。电路中的三个整流管D1~D3的作用是降低数码管的工作电压，增加其使用寿命。

图2－7显示器原理图

程序

程序：

;=====================定义参数=============================

LED_ON BIT 00H;数码管亮暗标志（1为亮，0为暗）

KEYCARD BIT 01H;按键标志

PWD_RIGHT BIT 02H;密码是否正确（1 为正确，0为错误）

KEY_LOCK BIT 03H;键盘锁定（1为锁，0为开）

SOND BIT P1.4;蜂鸣器

GREEN BIT P1.5;绿灯

RED BIT P1.6;红灯

LED1 EQU 50H;数码管自动变暗时间数1

KEYS EQU 53H;按键键值

KEY1 EQU 54H;按键行值

PWD1 EQU 56H;存密码1

PWD2 EQU 57H;存密码2

PWD3 EQU 58H;存密码3

PWD4 EQU 59H;存密码4

SHOW1 EQU 5AH;显示1

SHOW2 EQU 5BH;显示2

SHOW3 EQU 5CH;显示3

SHOW4 EQU 5DH;显示4

SHOW0 EQU 5EH;临时用

;====================程序开始==============================

ORG 0000H

AJMP INIT

;=====================初始化===============================

ORG 0030H

INIT:

MOV P0, #40H

MOV P2, #0FH

MOV P3, #00H

MOV LED1, #3FH

MOV KEYS, #00H

MOV KEY1, #00H

MOV SHOW0,#00H

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

LCALL PWD_INIT

SETB LED_ON

CLR PWD_RIGHT

SETB SOND

SETB RED

SETB GREEN

CLR KEY_LOCK

CLR KEYCARD

AJMP MAIN

;===========================================================主程序======================================================

MAIN:

MOV P2,#0FH

MOV P3,#00H

LCALL KEY_FIRST ;调用键盘程序

JNB KEYCARD,MAIN ;KEYCARD=0时，无键按下跳回MAIN

LCALL KEY_MAIN ;KEYCARD=0时，调用键盘处理程序

JNB KEYCARD,MAIN

LJMP MKEY_FUNCTION ;跳到主程序键盘各按键处理程序

;============================================================END========================================================

;=====================检测按键第一次按下========================

KEY_FIRST:

JNB LED_ON,KEY_LOOP

MOV A, P2 ;数码管亮时扫描

ANL A, #0FH ;屏敝掉高4位

CJNE A, #0FH,KEY_SECOND ;判断是否有键按下

CLR KEYCARD ;无键则KEYCARD置0

LCALL LED_DISPLAY ;调用显示子程序

DJNZ LED1, ESC

CLR LED_ON

MOV LED1, #03FH

ESC:

RET

KEY_LOOP: ;数码管暗时扫描

MOV A, P2

ANL A, #0FH

CJNE A, #0FH,KEY_SECOND

CLR KEYCARD

RET

;=======================检测按键第二次按下=================

KEY_SECOND:

LCALL BEEP1 ;按键响声

JNB LED_ON,KEY_EXIT1 ;如果LED是暗的，则置LED_ON为1

MOV LED1, #03FH

LCALL DELAY10MS ;去抖，延时10ms

MOV A, P2 ;重新扫描键盘

ANL A, #0FH

CJNE A, #0FH,KEY_EN ;有键按下，则置KEYCARD为1

CLR KEYCARD ;无键按下，则置KEYCARD为0

RET

KEY_EXIT1:

LCALL KEY_RELEASE

SETB LED_ON

RET

KEY_EN:

SETB KEYCARD ;置KEYCARD为1

RET

;===============================================KEY_MAIN=================================================

KEY_MAIN:

MOV R3,#0EH

MOV R4,#04H ;循环次数

KEY_ROW:

MOV P3,R3

MOV A,P2

ANL A,#0FH

MOV KEY1,R3 ;将行信息存到KEY1中

CJNE A,#0FH,KEY_WORD ;是该行则跳到键值计算程序

MOV A,R3

SETB C

RLC A ;带进位循环左移

ANL A,#0FH

MOV R3,A

DJNZ R4, KEY_ROW

CLR KEYCARD

RET

;================键值计算========================

KEY_WORD:

SWAP A

ORL A,KEY1 ;列＋行＝键值

MOV KEYS,A ;键值存到KEYS中

RET

;==================================主程序各按键功能=======================================

MKEY_FUNCTION:

MOV KEYS,A ;键值赋给A

MK0:

CJNE A,#0EEH,MK1

CLR KEYCARD

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

LCALL KEY_RELEASE ;按键松开程序

MOV R5,#05H

MOV R6,#03H

CLR KEY_LOCK

LOGIN_MAIN: ;输入密码主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;调用键盘扫描程序

JNB KEYCARD,LOGIN_MAIN

LCALL KEY_MAIN ;调用键盘处理程序

LJMP LKEY_FUNCTION ;跳到输密码时各键功能处理程序

MK1:

LCALL KEY_RELEASE

LJMP MAIN

;========＝＝＝＝＝＝＝＝=========================END====================================

;==========================出厂密码============================

PWD_INIT:

MOV PWD1, #01H

MOV PWD2, #02H

MOV PWD3, #03H

MOV PWD4, #04H

RET

;======================================输入密码时各按键功能====================================

LKEY_FUNCTION:

MOV A,KEYS

;=================无效键============================

LK0:

CJNE A,#0EEH,LK1

LCALL LAMP_RED ;闪红灯

LCALL KEY_RELEASE

LJMP LOGIN_MAIN ;返回输入密码主程序

LK1:

CJNE A,#0EDH,LK2

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

LK2:

CJNE A,#0EBH,LK3

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

;=================退出键==================

LK3:

CJNE A,#0E7H,LK4

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

CLR KEY_LOCK

LJMP MAIN ;返回主程序

;===============清除键=========================

LK4:

CJNE A,#07BH,LK5

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

MOV R5, #05H

LCALL KEY_RELEASE

LJMP LOGIN_MAIN

;================确定键=========================

LK5:

CJNE A,#077H,LK6

LCALL PWD_COMPARE ;调用密码检测子程序

LCALL KEY_RELEASE

JB PWD_RIGHT,SYS_LOGIN ;PWD_RIGHT为1时表示密码正确，跳到SYS_LOGIN

DJNZ R6,LK5_EXIT ;否则将输入次数R6减1

INC R6 ;若输入次数已经是3次了，就保持R6为1

SETB KEY_LOCK ;置KEY_LOCK为1

LK5_EXIT:

MOV SHOW1,#0BH

MOV SHOW2,#1BH

MOV SHOW3,#2BH

MOV SHOW4,#3BH

MOV R5, #05H

LK5_ESC:

LCALL KEY_RELEASE

LJMP LOGIN_MAIN ;返回输入密码主程序

;=============0-9数字键========================

LK6:

MOV R0,#00H

JB KEY_LOCK,LK6_EXIT ;置KEY_LOCK为1时锁定数字键

DJNZ R5,LKEY_NUM ;输入个数满4个则锁定数字键，否则R5减1

INC R5 ;若输入个数已经是4个了，就保持R5为1

LK6_EXIT:

LCALL BEEP2 ;误操作键盘发声

AJMP LK6_ESC

LKEY_NUM:

MOV A,R0

INC R0

MOV DPTR,#KEY_VALUE

MOVC A,@A DPTR

CJNE A,KEYS,LKEY_NUM

DEC R0

MOV A,R0

MOV DPTR,#TAB

MOVC A,@A DPTR

MOV KEYS,A

ORL A,#30H

MOV SHOW0,A

LCALL LED_MOVE ;调用左移功能

MOV SHOW4,SHOW0

LK6_ESC:

ACALL KEY_RELEASE

LJMP LOGIN_MAIN

;=======================================END=================================================

;================================登陆系统========================================

SYS_LOGIN:

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

CLR GREEN ;绿灯亮表示开锁成功

SYS_MAIN: ;开锁状态主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;调用键盘扫描程序

JNB KEYCARD,SYS_MAIN

LCALL KEY_MAIN ;调用键盘处理程序

LJMP SYSKEY_FUNCTION

;==================================登陆系统后各键功能===================================

SYSKEY_FUNCTION:

MOV A,KEYS

;================修改密码键===============

SYSK1:

CJNE A,#0EDH,SYSK2

SET_PWD:

MOV R5,#05H

CLR KEY_LOCK

MOV SHOW1,#0AH

MOV SHOW2,#1AH

MOV SHOW3,#2AH

MOV SHOW4,#3AH

SETPWD_MAIN: ;修改密码主程序

MOV P2, #0FH

MOV P3, #00H

LCALL KEY_FIRST ;调用键盘扫描程序

JNB KEYCARD,SETPWD_MAIN

LCALL KEY_MAIN ;调用键盘处理程序

LJMP SKEY_FUNCTION

;================恢复出厂设置===========

SYSK2:

CJNE A,#0EBH,SYSK3

LCALL PWD_INIT

LCALL KEY_RELEASE

LJMP SYS_MAIN

;=================退出键==================

SYSK3:

CJNE A,#0E7H,SYSK4

MOV SHOW1,#00H

MOV SHOW2,#10H

MOV SHOW3,#20H

MOV SHOW4,#30H

CLR KEY_LOCK

SETB GREEN ;关绿灯

LJMP MAIN ;跳回主程序

;==================无效键==================

SYSK4:

LCALL BEEP2

LCALL KEY_RELEASE

LJMP SYS_MAIN

;==================================END==================================================

;=================================修改密码各键功能==========================================

SKEY_FUNCTION:

MOV A,KEYS

;=================无效键=====================

SK0:

CJNE A,#0EEH,SK1

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

SK1:

CJNE A,#0EDH,SK2

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

SK2:

CJNE A,#0EBH,SK3

LCALL LAMP_RED

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

;=================退出修改密码================

SK3:

CJNE A,#0E7H,SK4

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

LCALL KEY_RELEASE

LJMP SYS_MAIN

;==================清除键=====================

SK4:

CJNE A,#07BH,SK5

MOV SHOW1,#0AH

MOV SHOW2,#1AH

MOV SHOW3,#2AH

MOV SHOW4,#3AH

MOV R5,#05H

LCALL KEY_RELEASE

LJMP SETPWD_MAIN

;=================确认键======================

SK5:

CJNE A,#077H,SK6

LCALL KEY_RELEASE

CJNE R5,#01H,SETPWD_FAIL ;当输入个数小于4个，则密码修改不成功

LCALL SETPWD_SUCCESS ;成功调用SETPWD_SUCCESS

LJMP SYS_MAIN

;================0-9数字键=================

SK6:

MOV R0,#00H

DJNZ R5,SKEY_NUM

INC R5

LCALL BEEP2

AJMP SK6_ESC

SKEY_NUM:

MOV A,R0

INC R0

MOV DPTR,#KEY_VALUE

MOVC A,@A DPTR

CJNE A,KEYS,SKEY_NUM

DEC R0

MOV A,R0

MOV DPTR,#TAB

MOVC A,@A DPTR

MOV KEYS,A

ORL A,#30H

MOV SHOW0,A

LCALL LED_MOVE

MOV SHOW4,SHOW0

SK6_ESC:

ACALL KEY_RELEASE

LJMP SETPWD_MAIN

;===========================================END=============================================

;====================================修改密码失败====================================

SETPWD_FAIL:

LJMP SET_PWD

;====================================修改密码成功==================================

SETPWD_SUCCESS:

ANL SHOW1,#0FH

ANL SHOW2,#0FH

ANL SHOW3,#0FH

ANL SHOW4,#0FH

MOV PWD1,SHOW1

MOV PWD2,SHOW2

MOV PWD3,SHOW3

MOV PWD4,SHOW4

MOV SHOW1,#01H

MOV SHOW2,#11H

MOV SHOW3,#21H

MOV SHOW4,#31H

LCALL LAMP_GREEN ;闪绿灯

RET

;=====================================左移功能==============================================

LED_MOVE:

CLR C

MOV A, SHOW2

SUBB A,#10H

MOV SHOW1,A

CLR C

MOV A, SHOW3

SUBB A,#10H

MOV SHOW2,A

CLR C

MOV A, SHOW4

SUBB A,#10H

MOV SHOW3,A

RET

;======================================密码检测========================================

PWD_COMPARE:

MOV A, SHOW1

ANL A, #0FH

CJNE A, PWD1,PWD_EXIT

MOV A, SHOW2

ANL A, #0FH

CJNE A, PWD2,PWD_EXIT

MOV A, SHOW3

ANL A, #0FH

CJNE A, PWD3,PWD_EXIT

MOV A, SHOW4

ANL A, #0FH

CJNE A, PWD4,PWD_EXIT

SETB PWD_RIGHT

AJMP PWD_ESC

PWD_EXIT:

CLR PWD_RIGHT

PWD_ESC:

RET

;======================================判断键是否释放====================================

KEY_RELEASE:

MOV P3,#00H

KEY_LOSEN:

MOV A,P2

ANL A,#0FH

LCALL LED_DISPLAY

CJNE A,#0FH,KEY_LOSEN

RET

;=======================================LED显示================================

LED_DISPLAY:

JNB LED_ON,LED_OFF

MOV P0, SHOW1

LCALL DELAY10MS

MOV P0, SHOW2

LCALL DELAY10MS

MOV P0, SHOW3

LCALL DELAY10MS

MOV P0, SHOW4

LCALL DELAY10MS

LED_OFF:

MOV P0, #4FH

RET

;========================正常按键响声===========================

BEEP1:

CLR SOND

LCALL DELAY1

SETB SOND

RET

;========================非法按键响声============================

BEEP2:

CLR SOND

LCALL DELAY100MS

LCALL DELAY100MS

SETB SOND

RET

;=========================操作有误闪红灯=================================

LAMP_RED:

MOV R2,#06H

MOV R1,#0FFH

LAMP_LOOP:

DJNZ R1,LAMP_LOOP

CPL RED

MOV R1,#0FFH

DJNZ R2,LAMP_LOOP

SETB RED

RET

;==========================修改密码成功闪绿灯==========================================

LAMP_GREEN:

MOV R2,#06H

MOV R1,#0FFH

LAMP_LOOP1:

DJNZ R1,LAMP_LOOP1

CPL GREEN

MOV R1,#0FFH

DJNZ R2,LAMP_LOOP1

CLR GREEN

RET

;========================10MS延时===========================

DELAY10MS:

MOV R2,#04H

LOOP3:

MOV R1,#0F9H

LOOP4:

DJNZ R1,LOOP4

DJNZ R2,LOOP3

RET

;========================100MS延时===========================

DELAY100MS:

MOV R2,#0FFH

LOOP7:

MOV R1,#0FFH

LOOP8:

DJNZ R1,LOOP8

DJNZ R2,LOOP7

RET

;=========================声音延时===========================

DELAY1:

MOV R2,#0FFH

LOOP5:

MOV R1,#03FH

LOOP6:

DJNZ R1,LOOP6

DJNZ R2,LOOP5

RET

;==========================键值表===========================

KEY_VALUE: DB 0EEH,0EDH,0EBH,0E7H,0DEH,0DDH,0DBH,0D7H,0BEH,0BDH,0BBH,0B7H,07EH,07DH,07BH,077H

;==========================数字表===========================

TAB: DB 00H,00H,00H,00H,00H,01H,02H,03H,04H,05H,06H,07H,08H,09H

预备知识：

1、 汇编语言语句一般格式为_____________。

2、 什么是寻址方式？寻址方式分为：____________、_____________、______________、

3、 传送指令的分类及其格式

4、 程序的基本结构有___________、_____________、_____________三种。

5、 按控制条件，循环程序可分为_____________和_____________两种形式。

6、 51系列的单片机的RAM为_____________,

7、 51系列的中断源为_____________个，_____________个优先级。

8、 总线分为_____________、_____________、_____________三类。

9、 什么是时钟周期、机器周期、指令周期？三者之间有何联系？

10、 在逻辑电路中，输入和输出只有两种状态，即_____________和_____________。通常以逻辑_____________和逻辑_____________表示电平高低

11、 常用逻辑电路有_____________、_____________、_____________、_____________、_____________、_____________。_____________。

12、 MCS-51的CPU能处理_____________位二进制数或代码。

13、 51系列共有_____________个_____________位的定时器/计数器。

14、 I/O是什么？I/O口是什么？

15、 MCS-51单片机在物理结构上有_____________个存储空间。分别是_____________、_____________、_____________、_____________。

16、 程序内存ROM寻址范围从_____________到_____________，容量为_____________KB。

17、 74138译码器有_____________个输入端：分别是_____________，

_____________个输出端，分别是_____________。

18、 80C51单片机共有_____________条指令，这些条指令共有_____________种寻址方式。

19、 操作码与操作数之间必须用_____________分开，操作数与操作数之间必须用逗号_____________分开。

20、 设某单片机系统的外接晶振频率为6MHz，使用定时器1以方式0产生周期为500ms的等宽正方波连续脉冲，并由P1.0输出。试写出其设计程序。

21、 说明下列指令中源操作数采用的寻址方式。

　MOV R5，R7

　MOV A，55H

　MOV A，＃55H

JMP @A DPTR

22、 段数码管从内部接线上分_____________和_____________两种

23、 机器语言指令由_______和_______两部分组成.

24、 八段码显示器的结构及其工作原理。

25、 如何用八段码显示器显示数字“3”？

流程卡：（2个课时）

操作流程卡　

课题电子密码锁的制作与维修

序号

操作内容

工作时间

学生： 日期： 教师：

电路板制作：（15个课时）

1、 准备本项任务所需的材料、工具，

2、 如果不全，缺哪些？

3、 根据上一项目的制作步骤进行操作。

材料明细卡

规格

名称

数量

74LS138

3线8线译码器

1片

2N3905

三极管

8个

AT89C51

单片机

1片

74LS48

BCD七段译码驱动器

1片

七段共阴极数码管

4片

1K

R1

1个

200

R2、R27

2个

5K

R3

1个

100

R4-R15、R22、R29-R32

17个

5K

R16-R21、R23-R26、R28

11个

33P

C1、C2

2个

22μ

C3

1个

D1-D3

3个

BUZ1

1个

齐套结构件、紧固件、电源线及插头

印刷电路板、

焊料、助焊剂、保险架（1副）、绝缘胶布

课题 密码锁的组装与维修

参考资料提示

序号

书名

出版社

1

电工基础

中国劳动社会保障出版社

2

电子电路基础

中国劳动社会保障出版社

3

数字逻辑电路

中国劳动社会保障出版社

4

电子技术工艺基础

电子工业出版社

5

电子专业技能训练

中国劳动社会保障出版社

6

电子技能与实训

电子工业出版社

7

MCS-51单片机原理及应用

天津大学出版社

8

单片机基础．

北京航空航天大学出版社

9

微机原理与汇编语言实用教程》

清华大学出版社

平分卡：（2个课时）

数字钟的组装与维修（满分100分）

评分页

姓名

学号

序号

项目及配分

工艺标准

扣分标准

学生自评分

教师评分

1

密码锁安装45分

1. 按图装配,元件的位置极性正确

2. 焊点光亮清洁焊料适量

3. 布线平直

4. 无漏焊虚焊假焊搭焊溅锡等现象

5. 焊接后元件引脚剪脚留头长度小于1 mm

6. 导线连接正确

7. 调谐机构转动灵活

8. 不损伤塑料件、绝缘层和表面涂覆层

1. 元件安装歪斜不对称, 每处扣1分

2. 错装漏装, 每处扣5分

3. 焊点不亮焊料过多过少布线不平直, 每处扣0.5分

4. 漏焊虚焊假焊搭焊溅锡, 每处扣3分

5. 剪脚留头长度大于1 mm, 每处扣0.5分

6. 导线连接错误，

7. 损伤塑料件、绝缘层和表面涂覆层，每处扣5分

8. 其它不符合工艺要求，

每处扣1分

2

密码锁的调试40分

1.正确测量主要技术指标

2．能够解决调试中出现的简单问题.

3.正确使用仪器仪表

1.测量步骤错误,每次扣3分

2.测量结果错误, 每次扣2分。误差大, 每次扣1分

3. 仪器仪表使用错误,每次扣3分

3

排除故障15分

故障判断5分

1. 能够正确观察故障现象

2. 能够正确分析故障原因，判断故障范围

1. 现象观察错误，每次扣2分

2. 故障原因分析错误，每次扣3分

3. 故障范围判断过大或过小，每次扣1分

故障检修10分

1． 检修思路清晰，方法运用得当

2． 检修结果正确

a) 检修思路不清，扣5分

b) 检修方法不当，每次扣3分

c) 检修结果错误，扣10分

4

安全文明操作

3. 安全用电,不人为损坏元器件加工件和设备等

4. 保持操作环境整洁,秩序井然,操作习惯良好

4. 发生安全事故,扣总分20分

5. 违反文明操作规程,视情况扣总分5---20分

5

合计

工作小结：（1个课时）

工作任务小结表

日期：

1：你所在的小组从接受任务到完成共用了多少时间？

2：你认为此密码锁的制作可以在哪些方面进行改进？

3：对你造成最大困难的是哪些工作？

4：你通过此密码锁的制作在哪些方面得到了提高？

5：你认为在今后的教学中是否还应按照这种教学方法来安排？